Twinkly.vb - Christmas tree lights with predefined and custom animations

[Moskus]

It's the same every year: "Why do we have to use these white lights? They are so... static." We've all been there.

Well, here's Twinkly. And here's the script where you can control some of it's functions.

Save the script as "Twinkly.vb", change the IP-address, and run the "Setup" sub.

'Moskus 2019-2020
    Dim IP As String
    Dim debug As Boolean = False

    Public Sub Main(ByVal something As Object)
    End Sub

    Public Sub ButtonPress(ByVal input As Object)
        Dim deviceRef As Integer = input(0)
        IP = DirectCast(hs.GetDeviceByRef(deviceRef), Scheduler.Classes.DeviceClass).Device_Type_String(hs)

        Dim cmd As String = input(1)
        If cmd.StartsWith("Brightness_") Then
            Dim value As Integer = cmd.Split("_")(1)
            DoCmd("Brightness", value)
        Else
            If DoCmd(cmd) Then hs.SetDeviceString(deviceRef, cmd, True)
        End If

        If DoCmd(cmd) Then hs.SetDeviceString(deviceRef, cmd.Replace("_", " "), True)
    End Sub

    Public Function DoCmd(ByVal command As String, Optional ByVal value As Integer = 100) As Boolean
        'SetMode("rt")
        'SetMode("demo")
        'SetMode("movie")
        'SetMode("effect")
        'SetMode("off")

        If debug Then hs.WriteLog("Twinkly", "Starting DoCmd()")
        Dim code As String = GetRandomCode()
        If debug Then hs.WriteLog("Twinkly", "Code: " & code)

        Dim auth As TwinklyAuthentication = Login(code, forceNew:=True)
        If debug Then hs.WriteLog("Twinkly", "Authentication_token: " & auth.authentication_token)

        Dim success As Boolean = Verify()
        If debug Then hs.WriteLog("Twinkly", "Verified: " & success)

        If command = "Brightness" Then
            SetBrightness(value)
        Else
            SetMode(command)
        End If
        Return True
    End Function

    Public Sub Setup(ByVal not_used As String)
        Dim new_ref As Integer = hs.NewDeviceRef("Twinkly")
        Dim dv As Scheduler.Classes.DeviceClass = hs.GetDeviceByRef(new_ref)
        dv.Location(hs) = "Twinkly"
        dv.Location2(hs) = "Twinkly"
        dv.Can_Dim(hs) = False
        dv.DeviceType_Set(hs) = New HomeSeerAPI.DeviceTypeInfo
        dv.Status_Support(hs) = True
        dv.Can_Dim(hs) = False
        dv.MISC_Set(hs, HomeSeerAPI.Enums.dvMISC.SHOW_VALUES) 'This is &H100
        dv.MISC_Clear(hs, HomeSeerAPI.Enums.dvMISC.STATUS_ONLY) 'This is &H10
        hs.SaveEventsDevices()

        AddDeviceButtons(new_ref)
        hs.WriteLog("Twinkly", "Initiation done!")
    End Sub


    Public Sub AddDeviceButtons(ByVal device_ref As String)
        Dim devID As Integer = CInt(device_ref)
        hs.DeviceScriptButton_DeleteAll(devID)
        hs.DeviceProperty_dvMISC(device_ref, HomeSeerAPI.Enums.eDeviceProperty.MISC_Set, HomeSeerAPI.Enums.dvMISC.SHOW_VALUES)

        Try
            hs.WriteLog("Twinkly", "Added button 1: " & hs.DeviceScriptButton_AddButton(devID, "Movie", 101, "Twinkly.vb", "ButtonPress", "Movie", 1, 1, 1))
            hs.WriteLog("Twinkly", "Added button 2: " & hs.DeviceScriptButton_AddButton(devID, "Effect", 102, "Twinkly.vb", "ButtonPress", "Effect", 1, 2, 1))
            hs.WriteLog("Twinkly", "Added button 3: " & hs.DeviceScriptButton_AddButton(devID, "Demo", 103, "Twinkly.vb", "ButtonPress", "Demo", 1, 3, 1))
            hs.WriteLog("Twinkly", "Added button 4: " & hs.DeviceScriptButton_AddButton(devID, "Pause", 104, "Twinkly.vb", "ButtonPress", "RT", 1, 4, 1))
            hs.WriteLog("Twinkly", "Added button 5: " & hs.DeviceScriptButton_AddButton(devID, "Off", 0, "Twinkly.vb", "ButtonPress", "Off", 1, 5, 1))

            For i As Integer = 10 To 100 Step 10
                hs.WriteLog("Twinkly", "Added dimming " & i & " : " & hs.DeviceScriptButton_AddButton(devID, (i & "%").ToString, i, "Twinkly.vb", "ButtonPress", "Brightness_" & i, 2 + Math.Floor(i / 51), (i / 10 - Math.Floor(i / 51) * 5), 1))
            Next

        Catch ex As Exception
            hs.WriteLog("Twinkly", "Error adding buttons: " & ex.Message)
        End Try
    End Sub

    Public Sub SetMovieConfig(ByVal frameDelay As Integer, ByVal numberOfLEDs As Integer, ByVal framesNumber As Integer, ByVal loopType As Integer)
        Dim data As New System.Collections.Generic.Dictionary(Of String, Integer)
        data.Add("frame_delay", frameDelay)
        data.Add("leds_number", numberOfLEDs)
        data.Add("frames_number", framesNumber)

        Dim output As String = RunAPI("led/movie/config", Newtonsoft.Json.JsonConvert.SerializeObject(data))
        If debug Then hs.WriteLog("Twinkly", "SetMovieConfig: " & output)
    End Sub

    Public Sub GetMovieConfig()
        ' {"frame_delay":66,"leds_number":175,"loop_type":0,"frames_number":212,"sync":{"mode":"none","slave_id":"","master_id":""},"code":1000}
        Dim output As String = RunAPI("led/movie/config")
        If debug Then hs.WriteLog("Twinkly", "GetMovieConfig: " & output)
    End Sub

    Public Sub GetMovieFull()
        If debug Then hs.WriteLog("Twinkly", "GetMovieFull: ")
        Dim output As Byte() = RunAPIraw("led/movie/all")
        If debug Then hs.WriteLog("Twinkly", ConvertByteArrayToString(output) & " ... done!")
    End Sub

    Public Sub SetMovieFull(ByVal octetString As String)
        Dim movie() As Byte = ConvertStringToByteArray(octetString)
        If debug Then hs.WriteLog("Twinkly", "SetMovieFull: ")
        Dim ret = RunAPIraw("led/movie/full", movie)
        If debug Then hs.WriteLog("Twinkly", System.Text.Encoding.ASCII.GetString(ret) & " ... done!")
    End Sub

    ''' <summary>
    ''' Get brightness
    ''' </summary>
    Public Function GetBrightness() As Integer
        Console.Write("Getting brigthness...")

        Dim output As String = RunAPI("led/out/brightness")
        Dim json = Newtonsoft.Json.JsonConvert.DeserializeObject(Of Object)(output)
        Return json("value")
    End Function

    ''' <summary>
    ''' Set brightness
    ''' </summary>
    ''' <param name="brightness">0-100</param>
    Public Sub SetBrightness(ByVal brightness As Integer)
        If debug Then hs.WriteLog("Twinkly", "Setting brigthness to '" & brightness & "'...")
        Dim data As New System.Collections.Generic.Dictionary(Of String, Object)
        data.Add("mode", "enabled")
        data.Add("value", brightness)
        data.Add("type", "A")

        Dim output As String = RunAPI("led/out/brightness", Newtonsoft.Json.JsonConvert.SerializeObject(data))
        If debug Then hs.WriteLog("Twinkly", IIf(output.Contains("1000"), " was a success!", " failed. :("))
    End Sub

    ''' <summary>
    ''' Sets the display
    ''' </summary>
    ''' <param name="mode">rt, movie, demo, restart, effect, off</param>
    Public Sub SetMode(ByVal mode As String)
        If debug Then hs.WriteLog("Twinkly", "Setting mode to '" & mode & "'")

        Dim data As New System.Collections.Generic.Dictionary(Of String, String)
        data.Add("mode", mode.ToLower())

        Dim output As String = RunAPI("led/mode", Newtonsoft.Json.JsonConvert.SerializeObject(data))
        Dim success As Boolean = output.Contains("1000")
        If debug Then hs.WriteLog("Twinkly", "Mode set: " & IIf(success, " was a success!", " failed. :("))
        If Not success And debug Then hs.WriteLog("Twinkly", "Output: " & output)
    End Sub

    Public Function GetAuthentication() As TwinklyAuthentication
        Dim auth As TwinklyAuthentication = New TwinklyAuthentication
        Dim authString As String = hs.GetINISetting("Twinkly", "Authentication", "", "Twinkly.ini")
        Try
            If authString <> "" Then
                auth = Newtonsoft.Json.JsonConvert.DeserializeObject(Of TwinklyAuthentication)(authString)
            End If
        Catch ex As Exception
        End Try

        Return auth
    End Function

    Public Function Verify() As Boolean
        Dim auth As TwinklyAuthentication = GetAuthentication()
        Dim data As New System.Collections.Generic.Dictionary(Of String, String)
        data.Add("challenge-response", auth.challengeresponse)

        Dim output As String = RunAPI("verify", Newtonsoft.Json.JsonConvert.SerializeObject(data))
        Return output.Contains("1000")
    End Function

    Public Function Login(ByVal challenge As String, Optional ByVal forceNew As Boolean = False) As TwinklyAuthentication
        Dim auth As TwinklyAuthentication = Nothing
        Dim authString As String = ""

        authString = hs.GetINISetting("Twinkly", "Authentication", "", "Twinkly.ini")
        Try
            If authString <> "" Then auth = Newtonsoft.Json.JsonConvert.DeserializeObject(Of TwinklyAuthentication)(authString)
        Catch ex As Exception
        End Try

        If auth Is Nothing OrElse forceNew Then
            Dim data As New System.Collections.Generic.Dictionary(Of String, String)
            data.Add("challenge", challenge)

            Dim output As String = RunAPI("login", Newtonsoft.Json.JsonConvert.SerializeObject(data))


            hs.SaveINISetting("Twinkly", "Authentication", output, "Twinkly.ini")
            auth = Newtonsoft.Json.JsonConvert.DeserializeObject(Of TwinklyAuthentication)(output)
        End If

        Return auth
    End Function

    Private Function RunAPI(ByVal urlFunction As String, Optional ByVal query As String = "") As String
        Dim source As String = ""
        Dim url As String = "http://" & IP & "/xled/v1/" & urlFunction
        Dim auth As TwinklyAuthentication = GetAuthentication()

        Using client As New System.Net.WebClient
            client.Headers.Add("Content-Type", "application/json")
            If auth.authentication_token <> "" Then
                client.Headers.Add("X-Auth-Token", auth.authentication_token)
            End If

            If query <> "" Then
                source = client.UploadString(url, "POST", query)
            Else
                source = client.DownloadString(url)
            End If
        End Using

        Return source
    End Function

    Private Function RunAPIraw(ByVal urlFunction As String, Optional ByVal bytes() As Byte = Nothing) As Byte()
        Dim auth As TwinklyAuthentication = GetAuthentication()
        Dim source As Byte() = {}

        Dim url As String = "http://" & IP & "/xled/v1/" & urlFunction
        Using client As New System.Net.WebClient
            Net.ServicePointManager.DefaultConnectionLimit = 9999
            client.Headers.Add("Content-Type", "application/octet-stream")
            If auth.authentication_token <> "" Then
                client.Headers.Add("X-Auth-Token", auth.authentication_token)
            End If

            If bytes IsNot Nothing Then
                source = client.UploadData(New Uri(url), bytes)
            Else
                source = client.DownloadData(url)
            End If
        End Using

        Return source
    End Function

    Public Function GetRandomCode(Optional ByVal forceNew As Boolean = False) As String
        Dim code As String = hs.GetINISetting("Twinkly", "Code", "", "Twinkly.ini")

        If code = "" OrElse forceNew Then
            code = GetRandomString(32)
            hs.SaveINISetting("Twinkly", "Code", code, "Twinkly.ini")
        End If

        Return code
    End Function

    Private Function GetRandomString(ByVal length As Integer)
        Dim s As String = "ABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789"
        Dim r As New Random
        Dim sb As New Text.StringBuilder
        For i As Integer = 0 To length - 1
            Dim idx As Integer = r.Next(0, 35)
            sb.Append(s.Substring(idx, 1))
        Next
        Return sb.ToString()
    End Function

    Public Function ConvertStringToByteArray(ByVal input As String) As Byte()
        Dim lst As New System.Collections.Generic.List(Of Byte)
        For i As Integer = 0 To input.Length - 1 Step 2
            Dim temp As String = input.Substring(i, 2)
            Dim val As Integer = Convert.ToInt32(temp, 16)
            lst.Add(Convert.ToByte(val))
        Next

        Return lst.ToArray()
    End Function

    Public Function ConvertByteArrayToString(ByVal bytes() As Byte) As String
        Dim ret As String = ""
        For Each b As Byte In bytes
            ret &= Convert.ToChar(b).ToString()
        Next
        Return ret
    End Function

    Public Class TwinklyAuthentication
        Private _authentication_token As String
        Public Property authentication_token() As String
            Get
                Return _authentication_token
            End Get
            Set(ByVal value As String)
                _authentication_token = value
            End Set
        End Property

        Private _authentication_token_expires_in As Integer
        Public Property authentication_token_expires_in() As Integer
            Get
                Return _authentication_token_expires_in
            End Get
            Set(ByVal value As Integer)
                _authentication_token_expires_in = value
            End Set
        End Property

        Private _challengeresponse As String
        Public Property challengeresponse() As String
            Get
                Return _challengeresponse
            End Get
            Set(ByVal value As String)
                _challengeresponse = value
            End Set
        End Property

        Private _code As Integer
        Public Property code() As Integer
            Get
                Return _code
            End Get
            Set(ByVal value As Integer)
                _code = value
            End Set
        End Property

    End Class​

After running the "Setup" function, you'll get a device with buttons.


Click on that device and go th toe Advanced tab. At the "Device Type (String)" field, enter the IP adress of your Twinkly device.


And remember to add the devie type string filter to your viewed devices:




NOTE!!
The script requires a reference to the Newntonsoft.Json.dll file. If you're using HS4, the scripting reference in settings.ini should look something like this:

ScriptingReferences=System.Core;System.Core.dll,Newtonsoft.Json;C:\Program Files (x86)\HomeSeer HS4\Bin\homeseer\Newtonsoft.Json.dll

For HS3, it should look something like this:
[CODE]ScriptingReferences=System.Core;System.Core.dll,Newtonsoft.J son;C:\Program Files (x86)\HomeSeer HS3\Bin\homeseer\Newtonsoft.Json.dll/CODE]
(you get the idea...)

[Traction Tim]

Hi Moskus, it looks good, but what lighting hardware will it work with ? I can't see it working with my static lights

[Moskus]

Hi Moskus, it looks good, but what lighting hardware will it work with ? I can't see it working with my static lights

--> https://twinkly.com/

[Rupp]

I need a pre lit Twinkly tree With the proliferation of prelits this company should jump on that wagon.

[bmsmithvb]

That is awesome! How would I plug this into HS3? I just bought these lights.

[Moskus]

That is awesome! How would I plug this into HS3? I just bought these lights.

The script is shown above. Copy that into a file called "Twinkly.vb". Make an Event that runs this script, and tell this action to run the sub or function "Setup". You will get a new device that can be used to control the lights.

[Paul vdK]

Hello Moskus,

What I am doing wrong.
I have twinkly hardware (2x icicle gen2)
changed the ip adress
i made the script => Running script in background: C:/Program Files (x86)/HomeSeer HS3/scripts/Twinkly.vb("Setup")
get errors below
- Compiling script C:\Program Files (x86)\HomeSeer HS3\scripts\Twinkly.vb: Namespace or type specified in the Imports 'System.Core' doesn't contain any public member or cannot be found. Make sure the namespace or the type is defined and contains at least one public member. Make sure the imported element name doesn't use any aliases.
- Compiling script C:\Program Files (x86)\HomeSeer HS3\scripts\Twinkly.vb: 'Newtonsoft' is not declared. It may be inaccessible due to its protection level.

[Moskus]

Ah sorry. You need a reference to the Newtonsoft.JSON.dll in your script settings.

[Paul vdK]

THX but where and how should I add that?

[Moskus]

In your settings.ini, Scriptingreference should look something like this:
ScriptingReferences=Newtonsoft.Json;Newtonsoft.Json.dll

[thomk]

Greetings,

Thanks for creating this!

By any chance, will this work on the Zee-S2? Or this a Windows-only script?

Thank you again!
Thom K.

[Moskus]

I can't think of a reason it shouldn't run on the Zee2. At least it works on Linux.

[Sparren]

Hello, this looks exactly as what I need for christmas. However I have problems seting it up.

I have added the reference to config.ini. This is the last part of if:

gFirstTimeStartup=False
io_interfaces=Z-Wave:
ScriptingReferences=Newtonsoft.Json;Newtonsoft.Json.dll
[Display]
gSelectedGroupWeb=All Groups

I still get error at startup that says:
Compiling script Startup.vb: Det gick inte att hitta biblioteket Newtonsoft.Json.dll
(cannot find library)

I'm running HS4
I can find the dll in bin/homeseer

[Moskus]

I can find the dll in bin/homeseer

Can you find it anywhere else?

[randy]

I need a pre lit Twinkly tree With the proliferation of prelits this company should jump on that wagon.

Lowe's has a Twinkly pre-lit tree this year.