This Day in History is History

[johnoc]

Well it's lasted for like 5 years without an issue, but it looks like the Yahoo page the This Day in History script pulls data from has finally changed, at least I think that's why I'm getting the following error:

5/5/2007 10:31:35 AM - Error - Running script, script run or compile error in file: on_this_day1.txt5:Invalid procedure call or argument: 'Mid' in line 42 More info: Invalid procedure call or argument: 'Mid'

The Yahoo site is actually pulling data from the The History Channel site which has an RSS feed, would it be better now a days to just pull the data from there? Here's the site if anyone would be willing to help put a script together:

http://www.history.com/tdih.do

and the RSS Feed is at:

http://feeds.feedburner.com/aetn/history/thisday

I tried to pull some vb language from another script and piece it together, but still can't get it to work... Any help would be awesome!

John

[tmcgowan]

I suspected that it was broke, when I kept hearing about the Shaker Founder Ann Lee was born on March 1st, 1736 every morning since March 1st at 6:30 in the morning when the script ran:

March 1 - SHAKER FOUNDER ANN LEE BORN in 1736 Ann Lee, the founder of the United Society of Believers in Christ's Second Appearing, a group commonly known as the Shakers, was born in Manchester, England. "Mother" Ann broke from the Quakers in 1770 to establish her own Christian movement based on celibacy, sexual equality, energetic worship, pacifism and a communal economy. Four years later, Lee led her flock to the New World, and in the years between the American Revolution and the Civil War, Shakers in America numbered 17,000. Today, the Shakers are best known for their simple yet masterfully designed furniture and architecture.

I'm not that good at writing or fixing these types of complex scripts, so I would second the motion to support someone in fixing it.

[Rupp]

If you guys find an XML feed for this day in history I can rework the script for you guys.

[Jebus]

Working Here...

On This Day in History
May 5 - IRA'S BOBBY SANDS DIES in 1981While imprisoned in Belfast, Bobby Sands led other members of the Irish Republican Army on a hunger strike in protest against being treated as criminals rather than political prisoners. The 27-year old Sands had been elected to Parliament while serving his 14-year sentence for weapons possession. After refusing food for 66 days, Sands died on May 5, 1981.


....JG

[Fuego]

Hate fixing other people's code (and haven't even looked at it), but this working VB.Net code snippet may give you pointers, or be of use directly.

' This Day in History script
' Fuego
 
Imports System.Xml
 
Sub ThisDayInHistory()
    Const URL As String = "http://feeds.feedburner.com/aetn/history/thisday"
    Const Node As String = "rss/channel/item"
    Dim XMLDoc As New XmlDocument
    XMLDoc.Load(URL)
    Dim XMLNode As XmlNode = XMLDoc.SelectSingleNode(Node)
    Dim Title As String = StripHTML(XMLNode.Item("title").InnerText)
    Dim Descr As String = StripHTML(XMLNode.Item("description").InnerText)
    hs.Speak("This day in history.")
    hs.Speak(Title)
    hs.Speak(Descr)
End Sub
 
Private Function StripHTML(ByVal HTML As String) As String
    Return System.Text.RegularExpressions.Regex.Replace(HTML, "<[^>]*>", "")
End Function

[griffined]

I get an error when I try and run the code snippet above, which I saved as a .vb file.

5/7/2007 8:54:12 AM Info Running script in background: thisdayinhistory.vb
5/7/2007 8:54:12 AM Error Script compile error: Type 'XmlDocument' is not defined.on line 19
5/7/2007 8:54:12 AM SCR Option Strict OffImports System.Xmlimports Schedulerimports SystemPublic Module scriptcode5#Region "Automatically generated code, do not modify"'Automatically generated code, do not modify'Event Sources Begin Public WithEvents hs As Scheduler.hsapplication Public WithEvents hsp As scheduler.hsp Public WithEvents hssystem As scheduler.phone0'Event Sources End'End of automatically generated code#End Region Sub ThisDayInHistory() Const URL As String = "http://feeds.feedburner.com/aetn/history/thisday" Const Node As String = "rss/channel/item" Dim XMLDoc As New XmlDocument XMLDoc.Load(URL) Dim XMLNode As XmlNode = XMLDoc.SelectSingleNode(Node) Dim Title As String = StripHTML(XMLNode.Item("title").InnerText) Dim Descr As String = StripHTML(XMLNode.Item("description").InnerText) hs.Speak("This day in history.") hs.Speak(Title) hs.Speak(Descr)End Sub Private Function StripHTML(ByVal HTML As String) As String Return System.Text.RegularExpressions.Regex.Replace(HTML, "<[^>]*>", "")End FunctionEnd Module

Did I miss something simple here?

[jon00]

In your settings.ini under [settings] add the following entry:

ScriptingReferences=System.XML;System.XML.dll

It should now work after a reboot of HS.

[Fuego]

Thanks for pointing that out Jon.

Other handy ones to have (whilst you're editing it) - IMHO - are:

ScriptingReferences = System.XML;System.XML.dll,System.Web;System.Web.dll,System.D ata;System.Data.dll,System.Management;System.Management.dll

(Not sure why a space shows up in D ata above - it shouldn't be there, but I can't remove it)

[griffined]

Thanks, I made that entry in my ini file, and it did fix the error I posted above.

This is the new error.

5/8/2007 12:27:18 PM Error 1 Running script thisdayinhistory.vb :method not found

[jon00]

Change:

Sub ThisDayInHistory()

to

Sub Main(parm as object)

see if that works.

[griffined]

That fixed it. Thanks a lot, I'll have this run every morning after the House status changes to Awake.

[johnoc]

It works great.... Thanks Jon!!

[stevea]

So I haven't been following this thread, but... Can someone post the resulting script that does work? I'd rather not try and follow the recipe steps in the thread.

Steve

[jon00]

If not already in your settings.ini file, add the following:

ScriptingReferences=System.XML;System.XML.dll

Reboot Homeseer if you need to add it.

Next copy the script below in a text editor and call it ThisDayHistory.vb

' This Day in History script
' Fuego
 
Imports System.Xml
 
Sub Main(parm as object)
    Const URL As String = "http://feeds.feedburner.com/aetn/history/thisday"
    Const Node As String = "rss/channel/item"
    Dim XMLDoc As New XmlDocument
    XMLDoc.Load(URL)
    Dim XMLNode As XmlNode = XMLDoc.SelectSingleNode(Node)
    Dim Title As String = StripHTML(XMLNode.Item("title").InnerText)
    Dim Descr As String = StripHTML(XMLNode.Item("description").InnerText)
    hs.Speak("This day in history.")
    hs.Speak(Title)
    hs.Speak(Descr)
End Sub
 
Private Function StripHTML(ByVal HTML As String) As String
    Return System.Text.RegularExpressions.Regex.Replace(HTML, "<[^>]*>", "")
End Function 

Now run the script via an event!

[drozwood90]

hmm...the day in history thing is still working fine for me...

I think I had tweaked something a while ago...but it's still working fine.

--Dan